//  ___________________________________________________________________________
// /                                                                           \
// |                                                                            |
// |                | |__  _ __ / \ | |_| |__   ___ _ __   __ _                 |
// |                | '_ \| '__/ _ \| __| '_ \ / _ \ '_ \ / _` |                |
// |                | |_) | | / ___ \ |_| | | |  __/ | | | (_| |                |
// |                |_.__/|_|/_/   \_\__|_| |_|\___|_| |_|\__,_                 |
// |                                                                            |
// |                              brAthena Script                               |
// |----------------------------------------------------------------------------|
// | Nome do Script: rankingpvp.txt                                             |
// |----------------------------------------------------------------------------|
// | Criado por: brAthena Dev. Team                                             |
// |----------------------------------------------------------------------------|
// | Versões brA: 1.0                                                           |
// |----------------------------------------------------------------------------|
// | Descrição: NPC que captura e cria um ranking em mapas pvp escolhidos.      |
// | Possui muitas variáveis e pode ser adaptado facilmente a diferentes tipos  |
// | de servidores. Pode-se habilitar ou desabilitar recursos através de chaves.|
// | Para maiores informações consulte o tópico oficial no brAthena.            |
// |----------------------------------------------------------------------------|
// | Changelog:                                                                 |
// | 0.9 Script Criado, versão de testes. [Equipe brAthena]                     |
// | 0.9.1 Corrigido algumas mensagems de debug. [Equipe brAthena]              |
// | 0.9.2 Corrigido mais mensagems e revisado essa parte. [Equipe brAthena]    |
// | 1.0 Bugs menores que foram encontrados, foram corrigidos.                  |
// |     Já houve um bom período de testes, 1.0 lançado. [Equipe brAthena]      |
// \___________________________________________________________________________/
prontera,164,172,3	script	PvP Ranking#brA	56,{

	function resetaHistoricoPvP;
	function addMorte;
	function addKill;
	function addBonus;
	function registraJogador;
	
	if(.iniciado == 1)
		goto L_CHAT;

OnInit:
	// **************************** Início das Configurações ****************************
	
	// ***** Principal *****
	set .name$,"[PvP Ranking]"; // Nome do NPC
	set $@debugMode,    0;  // Habilite apenas se quiser receber mensagems de debug, para desenvolvedores
	set $@secureMode,   1;  // Detecta erros sérios e os exibe no console do map-server
	set .Tamanho,       30; // Tamanho do Ranking
	set .Pagina,        15; // Ver quantos por página
	set .Chat,          1;  // ChatRoom no NPC escrito: "Ranking Top .Tamanho"
	set .LevelRankOn,   10; // Nível de GM ABAIXO ou IGUAL disso apareçe no Ranking
	set .LevelGM,       80; // Nível para Acessar o Painel de Controle: Deletar e refrescar usuários individualmente.
	set .LevelAdmin,    99; // Nível de GM ACIMA ou IGUAL disso pode Resetar o ranking e modificar os prêmios.
	
	// ***** Pontuação *****
	set .add_pontos,	2; // Quantos pontos ganha matando um jogador ?
	set .rem_pontos,	1; // Quantos pontos PERDE quando o jogador morre ? [Não precisa adicionar o '-' (menos) !!! ] [Não é possivel fazer este valor ser positivo, deixe como 0 ou superior]
	
	// *** Add-On: Anti-Spam ***
	set .AntiSpam,      1;  // Anti-Spam habilitado ou não. 1: sim; 0: não.
	set $@AS_Refresh,   10;  // Tempo em minutos para o refresh.
	set .AS_Multiplica, 20; // Valor para cada multiplicador. Veja o tópico oficial no brAthena.
	set $@AS_Limit,     5;  // Número de jogadores diferentes que o Anti-Spam guardará a cada instante. Mantenha esse valor baixo. Limite de 128.
	
	// *** Add-On: Sistema de Anúncios ***
	set .Anuncio,       1;  // Anuncia quando o jogador passar de nível no Ranking ? 0: Não; 1: Sim, somente para o jogador; 2: Anúncia somente no mapa; 3: Anuncia global
	set .AnuncioPadrao, 1;  // Caso '.Anuncio' esteja funcional, o jogador sempre pode alterar a configuração de anúncio no NPC. Mas o padrão é Sim ou Não para os anúncios? 1: Sim, 0: Não.
	
	// *** Add-On: Prêmios ***
	// Prêmio para os 1°, 2° e 3° jogadores.
	setarray .PremiosIDs[0],675,675,673; // IDs. dos prêmios
	setarray .PremiosQuant[0],5,3,2; // Quant. do prêmio
	set .Rank_Days_Min, 20; // Número de dias que, por segurança, será um período forçado entre uma entrega de prêmios pelo ranking. Nem mesmo seus [GM]s confiáveis podem alterar este valor.
	
	// *** Add-On: Bônus ***
	set .Bonus, 1;	// Bonus em pontos que o jogador ganha quando atinge certo estágio por invictividade ou múltiplos kills.
	
	// Bônus dados por INVICTIVIDADE
	setarray .indexInvicto[0],	3, 5, 7, 9, 11, 13, 15, 17 , 2147483647; // Não retire o valor "2147483647".
	setarray .bonusInvicto[0],	1, 1, 1, 1, 1, 	1, 	2, 	2;
	setarray .fraseInvicto$[0],	"Você acaba de ganhar ", " ponto(s) de bônus por sua invictividade à ", " batalhas !";
	
	// Bônus dados por MÚLTIPLOS KILLS
	setarray .indexMultiplo[0],	2, 3, 4, 5, 6, 7, 8, 9, 2147483647;
	setarray .bonusMultiplo[0],	2, 2, 3, 3, 4, 4, 5, 5;
	setarray .fraseMultiplo$[0], "Você acaba de ganhar ", " ponto(s) de bônus por matar ", " oponentes ao mesmo tempo !";
	
	
	// *** Add-On: Soms DotA/Unreal Tournament ***
	set .Soms, 0;	// Soms do DotA/Unreal Tornament habilitados ? Necessário baixar os arquivos no tópico oficial do brAthena.
	
	// Soms que são emitidos por INVICTIVIDADE
	setarray .tipoDeSom[0],	0, 3, 5, 7, 9, 11, 13, 15, 17,  2147483647;
	setarray .nomesWAV$[0],	"firstblood.wav", "killingspree.wav", "rampage.wav", "ownage.wav", "dominating.wav", "unstoppable.wav", "wickedsick.wav",   "godlike.wav", "holyshit.wav";
	setarray .fraseSom$[0],	"is FIRST BLOOD", "is KILLING SPREE", "is RAMPAGE",  "is OWNAGE",  "is DOMINATING",  "is UNSTOPPABLE",  "is a WICKED SICK", "is GODLIKE",  "is more than GODLIKE";
	
	// Soms que são emitidos por "MULTIPLE KILL"
	setarray .tipoDeSom2[0],	2, 3, 4, 5, 6,  2147483647;
	setarray .nomesWAV2$[0],	"doublekill.wav", "triplekill.wav",   "megakill.wav",   "ultrakill.wav",  "monsterkill.wav";
	setarray .fraseSom2$[0],	"fez DOUBLE KILL", "fez TRIPLE KILL", "fez MEGA KILL",  "fez ULTRA KILL", "fez MO-MO-MONSTER KILL";
	
	set $@delay_combo, 8; // Tempo em segundos em que você fica no "combo". Para dar double kill você precisa matar duas pessoas neste intervalo de tempo.
	                     // Obs: Caso coincide uma mensagem por Tempo com uma por Invictividade, soltará a mensagem por Tempo. Mas as duas continuarão contando e funcionantes.
	set .SomAnuncio, 1;  // Como o anúncio dos soms será mostrado? 1: Na área ao redor do jogador. 2: No mapa inteiro do jogador.
	
	// *** Add-On: Mapas dinamicos ***
	// Os mapas são globais para que você possa alterar em outros scripts, dinamicamente.
	// Você pode colocar aqui os mapas fixos e adicionar e/ou remover temporariamente através das funções "addRankMap"/"rmRankMap". Veja mais no tópico oficial no brAthena.
	setarray $@maps_pRank$[0],	"pvp_y_1-1",
								"pvp_y_1-5";
	
	// *** Outros ***
	
	//Configuração de Cores. Posição		Nome	Pontos		Kills		Mortes		Profissão
	setarray .colour$[0],	"^996600",	"^006699",	"^0524E9",	"^00AA00",	"^FF0000", "^046B6B";
	
	// **************************** Final das Configurações ****************************
	
	set $@qtyMaps, getarraysize($@maps_pRank$);
	
	while( .tipoDeSom[.@i] < 2147483647 ) set .@i, .@i + 1;
	set .maxSom, .@i - 1;
	
	if(.Chat){
		waitingroom "PvP Top "+.Tamanho,0;
	}
	
	set .iniciado, 1;
	end;
	
	L_CHAT:
	
	mes .name$;
	mes "Olá "+strcharinfo(0)+"...";
	mes "Posso lhe mostrar o Ranking PvP do servidor, inclusive sobre seus status aqui.";
	next;
	Menu_Inicial:
	if ( getgmlevel() >= .LevelGM )
		menu "[GM MENU]",GMMenu,"[USER MENU]",UserMenu;

	UserMenu:
	switch(select("Me mostre o Ranking","Estatísticas desde meu login","Estatísticas deste personagem","Estatística de minha conta","Opções","Sair"))
	{
		case 1:
		if(#modo == 1) goto L_MODO2;
		mes .name$;
		mes "Okay.. Vou lhe mostrar o Ranking "+.Tamanho+" PvP com "+.Pagina+" entradas por página.";
		mes "Vai ser mostrado assim:";
		mes .colour$[0]+"Lugar: "+.colour$[1]+"<Nome> ~ "+.colour$[2]+"<Pontos> "+.colour$[3]+"<Matou>:"+.colour$[4]+"<Morreu> "+.colour$[5]+"<Profissão>";
		next;
		query_sql "SELECT name , points, kills , deaths , job FROM top_pvp ORDER BY points DESC LIMIT "+.Tamanho+"",.@fname$,.@fpontos,.@fkills,.@fdeaths,.@fjob;
		set @inexato, 1;
		if( (.Tamanho/.Pagina)*.Pagina == .Tamanho){ set @inexato, 0; }
		for (set @y,0; @y < .Tamanho/.Pagina+@inexato; set @y,@y+1){
			for (set @x,@y*.Pagina; @x < .Tamanho && @x < (@y+1)*.Pagina; set @x,@x+1){
				if (.@fname$[@x] != ""){//.colour$[1]+
					mes .colour$[0]+(@x+1)+": ^000000 ^0064D7"+.@fname$[@x]+" ~"+.colour$[2]+" "+.@fpontos[@x]+" "+.colour$[3]+.@fkills[@x]+":"+.colour$[4]+.@fdeaths[@x]+"^000000 "+.colour$[5]+jobname(.@fjob[@x])+"";
				} else {
					mes "^DD0000"+(@x+1)+": ^006699Nenhum!^000000 ";
				}
			}
		//if( @x != .Tamanho) next;
		next;
		}
		break;

		L_MODO2:
		mes .name$;
		mes "Okay.. Vou lhe mostrar o Ranking "+.Tamanho+" PvP no modo de vizualização 2.";
		next;
		query_sql "SELECT name, points, kills, deaths, job FROM top_pvp ORDER BY points DESC LIMIT "+.Tamanho+"",@guild_name$,@guild_pontos,@guild_kills,@guild_deaths,@job;
		dispbottom "Ranking PvP [TOP "+.Tamanho+"]";
		dispbottom " ";
		dispbottom "Posição° = Nome do char --> Pontos (Kills <~> Deaths) Profissão";
		dispbottom " ";
		for(set .@i,0;.@i<.Tamanho;set .@i,.@i+1) {
			dispbottom "["+(.@i+1)+"] <~> "+@guild_name$[.@i]+" --> "+@guild_pontos[.@i]+" ("+@guild_kills[.@i]+" <~> "+@guild_deaths[.@i]+") - "+jobname(@job[.@i])+"";
		}
		close;
		
		case 2:
		mes .name$;
		mes "Desde o login você fez "+.colour$[2]+""+@pvpPoints+"^000000 pontos !";
		mes .colour$[3]+""+@pvpKills+"/"+.colour$[4]+""+@pvpDeaths+"^000000(Kills/Mortes)";
		next;
		break;

		case 3:
		query_sql "SELECT points, kills, deaths FROM top_pvp WHERE `char_id` = '"+getcharid(0)+"' LIMIT 1",.@pontos,.@kills,.@deaths;
		mes .name$;
		mes "Com este personagem você já fez "+.colour$[2]+""+.@pontos+"^000000 pontos !";
		mes .colour$[3]+""+.@kills+"/"+.colour$[4]+""+.@deaths+"^000000(Kills/Mortes)";
		next;
		break;

		case 4:
		set .@maxx, query_sql("SELECT `char_id` FROM `char` WHERE `account_id` LIKE " +getcharid(3)+ " LIMIT 128",.@charids);
		set .@ddeaths,0;
		set .@kkils, 0;
		set .@ppontos, 0;
		for(set .@i, 0; .@i < .@maxx; set .@i,.@i + 1)
		{
			if( query_sql("SELECT points, kills, deaths FROM top_pvp WHERE `char_id` = '"+.@charids[.@i]+"' LIMIT 1",.@pontos,.@kills,.@deaths) )
			{
				set .@ppontos, .@ppontos + .@pontos;
				set .@kkills, .@kkills + .@kills;
				set .@ddeaths, .@ddeaths + .@deaths;
			}
		}
		mes .name$;
		mes "Em toda sua conta você já fez "+.colour$[2]+""+.@ppontos+"^000000 pontos !";
		mes .colour$[3]+""+.@kkills+"/"+.colour$[4]+""+.@ddeaths+"^000000(Kills/Mortes)";
		next;
		break;

		case 5:
		mes .name$;
		mes "Você pode mudar a sua opção de Visualização do Chat ou dos anúncios.";
		mes "Sobre qual você deseja mudar ?";
		next;
		if (select ("Mudar o Chat","Mudar Anúncios") == 2) goto L_Opcao_Mensagems;
		mes .name$;
		mes "Você pode escolher entre a visualização dentro do NPC ou fora.";
		mes "Qual você deseja ?";
		next;
		set #modo, select("Dentro do NPC (colorido) ","Fora do NPC (verde claro)")-1;
		mes .name$;
		mes "Muito bem !";
		mes "Suas configurações foram salvas.";
		next;
		break;
		
		case 6:
		mes .name$;
		mes "OK. Volte se precisar de algo.";
		close;
	}
	goto Menu_Inicial;

	L_Opcao_Mensagems:
	mes .name$;
	mes "Muito bem, a pergunta envolve sua privacidade.";
	mes "Você gostaria de ter seu nome anunciado quando você subir de nível no Ranking ?";
	next;
	switch(select("Claro, porque não ?","Não, obrigado"))
	{
		case 1:
			set @valor, 1;
			break;
		case 2:
			set @valor, 2;
			break;
	}
	mes .name$;
	mes "Você gostaria que essa opção";
	mes "Funcione em toda sua conta ou apenas neste personagem ?";
	next;
	switch(select("Em toda minha conta","Apenas a este personagem"))
	{
		case 1:
			set #pvpmensagem,@valor;
			break;
		case 2:
			set pvpmensagem, @valor;
			break;
	}
	mes .name$;
	mes "Okay, "+strcharinfo(0)+"";
	mes "Suas opções foram mudadas! Obrigado e tenha um bom jogo";
	next;
	goto Menu_Inicial;
	
	GMMenu:
	mes "^358109brAthena PvP Ranking^000000";
	mes "Versão: ^3581091.0^000000";
	mes "Como posso ajudá-lo ?";
	next;
	menu "Resetar Ranking",L_resetar,"Deletar um jogador do Ranking",L_deletarchar,"Recarregar um char do ranking",L_refreshchar,"Configurações de Prêmios",L_rewards,"Ajuda",L_ajuda,"Cancelar",L_end;
	
	mes "^358109brAthena PvP Ranking^000000";
	mes "Caro administrador, a opção de resetar ranking faz exatamente o que propõe.";
	mes "As tabelas do MySQL do Ranking sofrerão uma limpeza.";
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "A opção de deletar um jogador do ranking, resetará todos os pontos, kills e mortes dele.";
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "A opção de recarregar um char lerá novamente o nome do jogador e a sua profissão, somente isso.";
	mes "Útil quando um determinado jogador renomeou seu personagem e no Ranking persiste seu antigo nome.";
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "O incoveniente dessa opção é que você precisará colocar o nome ATUAL dele, isso poderá ser mudado nas futuras versões.";
	next;
	goto GMMenu;
	
L_rewards:
	if (getgmlevel() < .LevelAdmin){
		mes "^358109brAthena PvP Ranking^000000";
		mes "Você não possui nível suficiente para fazer isso.";
		next;
		goto GMMenu;
	}
	set .@num, 3; // Não altere.
	mes "^358109brAthena PvP Ranking^000000";
	mes "O prêmio do ranking atualmente é este:";
	set .@max, getarraysize(.PremiosIDs);
	for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
	{
		mes (.@i+1)+"° Jogador: "+.PremiosQuant[.@i]+"x "+getitemname(.PremiosIDs[.@i]);
	}
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Deseja alterá-lo ?";
	next;
	if (select ("Sim","Não") == 2) goto L_end;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Caro administrador, vou pedir para você digitar cada item e a respectiva quantidade.";
	mes "^FF0000Aviso que esta opção serve apenas para temporariamente mudar os prêmios, até o próximo restart do servidor.";
	mes "^FF0000Para mudar permanentemente é necessário ^0011FFeditar o NPC.";
	next;
	for(set .@num,0; .@num < .Tamanho; set .@num, .@num +1){
		mes "^358109brAthena PvP Ranking^000000";
		mes "Digite por favor o prêmio (ID) do "+(.@num+1)+"° colocado: (0 para parar)";
		input .PremiosIDs[.@num];
		if( .PremiosIDs[.@num] == 0) break;
		next;
		mes "^358109brAthena PvP Ranking^000000";
		mes "Digite por favor a quantidade do prêmio do "+(.@num+1)+"° colocado:";
		input .PremiosQuant[.@num];
		next;
	}
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "O prêmio do ranking AGORA é este:";
	set .@max, getarraysize(.PremiosIDs);
	for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
	{
		mes (.@i+1)+"° Jogador: "+.PremiosQuant[.@i]+"x "+getitemname(.PremiosIDs[.@i]);
	}
	next;
	goto GMMenu;
	
	
L_ajuda:
	mes "^358109brAthena PvP Ranking^000000";
	mes "A opção de recarregar um char lerá novamente o nome do jogador e a sua profissão, somente isso.";
	mes "Útil quando um determinado jogador renomeou seu personagem mas no Ranking persiste seu antigo nome.";
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "O incoveniente dessa opção é que você precisará colocar o nome ATUAL dele, isso poderá ser mudado nas futuras versões.";
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "As outras opções são óbvias demais para serem esclarecidas";
	mes "Resetar o ranking, deletar um char do ranking e configurar os prêmios são funções que fazem justamente o que o nome lhes condiz.";
	next;
	goto GMMenu;
	
L_deletarchar:
	if (getgmlevel() < .LevelGM) end; // Como ele chegou aqui ?
	mes "^358109brAthena PvP Ranking^000000";
	mes "Deseja deletar algum char do Ranking?";
	if (select ("Sim","Não") == 2) goto L_end;
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Por favor me diga o nome do char";
	input .@charLadderInput$;
	set .@deletecharID, 0;
	if (query_sql("SELECT `char_id` FROM `char` WHERE `name` = '"+.@charLadderInput$+"' LIMIT 1",.@deletecharID) == 1){
		query_sql("UPDATE `top_pvp` SET `points` = '0',`kills` = '0',`deaths` = '0' WHERE `char_id` ="+.@deletecharID+"");
		mes "Foi feita uma tentativa de deletar o char com ID = "+.@deletecharID;
		mes "Por favor verifique se ele não consta mais na lista.";
		next;
		goto GMMenu;
	}
	else{
		mes "Desculpe, mas não consegui encontrar um usuário com este nome.";
		mes "Verifique acentos e espaços em branco, trocar o caracter 'I' (i maiúsculo) pelo caracter 'l' (L minúsculo)";
		next;
		goto GMMenu;	
	}

L_refreshchar:
	if (getgmlevel() < .LevelGM) end; // Como ele chegou aqui ?
	mes "^358109brAthena PvP Ranking^000000";
	mes "Deseja recarregar algum jogador no Ranking?";
	if (select ("Sim","Não") == 2) goto L_end;
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Por favor me diga o nome atual e verdadeiro do personagem em questão";
	input .@charLadderInput$;
	if (query_sql("SELECT `char_id` FROM `char` WHERE `name` = '"+.@charLadderInput$+"' LIMIT 1",.@refreshcharID) == 1){
		query_sql("SELECT `class` FROM `char` WHERE `char_id`="+.@refreshcharID+"",.@jobchar);
		query_sql("UPDATE `top_pvp` SET `name` = '"+.@charLadderInput$+"',`job` = '"+.@jobchar+"' WHERE `char_id` ="+.@refreshcharID+"");
		mes "Foi feita uma tentativa de recarregar o char com ID = "+.@refreshcharID;
		mes "Por favor verifique se ele agora consta corretamente na lista.";
		next;
		goto GMMenu;
	}
	else{
		mes "Desculpe, mas não consegui encontrar um usuário com este nome.";
		mes "Verifique acentos e espaços em branco, trocar o caracter 'I' (i maiúsculo) pelo caracter 'l' (L minúsculo)";
		next;
		goto GMMenu;	
	}
	
L_resetar:
	if (getgmlevel() < .LevelAdmin){
		mes "^358109brAthena PvP Ranking^000000";
		mes "Você não possui nível suficiente para fazer isso.";
		next;
		goto GMMenu;
	}
	mes "^358109brAthena PvP Ranking^000000";
	mes "O prêmio do ranking atualmente é este:";
	set .@max, getarraysize(.PremiosIDs);
	for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
	{
		mes (.@i+1)+"° Jogador: "+.PremiosQuant[.@i]+"x "+getitemname(.PremiosIDs[.@i]);
	}
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Você deseja continuar com a operação ?";
	next;
	if (select ("Sim","Não") == 2) goto L_end;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Você deseja que antes de resetá-lo eu envie prêmios aos três primeiros do Ranking ?";
	mes "Eles receberão estes prêmios automaticamente assim que logarem.";
	mes "O prêmio é entregue somente quando ele conectar o personagem específico que ganhou o ranking."; // Utilizando o personagem específico, pode-se adicionar items que são trancados ao char com segurança ou até rental items.
	next;
	menu "Sim, envie os prêmios",-,"Não, resete mas não de prêmios",L_sempremio,"Cancelar",L_end;
	
	query_sql "SELECT char_id, name , points FROM top_pvp ORDER BY points DESC LIMIT 30",.@fcids,.@fname$,.@fpontos;
	set .TimeNow, gettimetick(2);
	set .Difftime, .TimeNow - $LastTimeRNK;
	if(.Difftime < (.Rank_Days_Min*60*60*24) ){
		mes "^358109brAthena PvP Ranking^000000";
		mes "Sinto muito, mas não posso deixar você dar prêmios se não se passaram "+.Rank_Days_Min+" dias desde o último Reset, faltam "+((.Rank_Days_Min*60*60*24)-.Difftime)+" segundos.";
		next;
		if (select ("Resete assim mesmo","Ok, pare por aqui.") == 2) goto L_end;
	}
	else{
		set $LastTimeRNK, gettimetick(2);
		for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
		{
			if( .@fcids[.@i] ){
				set $premioRnkCid[.@i], .@fcids[.@i];
				set $premioRnkEnabled[.@i], 1;
			}
		}
	}
	mes "^358109brAthena PvP Ranking^000000";
	mes "Okay, os premiados serão esses:";
	for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
	{
		mes (.@i+1)+"° "+.@fname$[.@i]+" Vai ganhar "+.PremiosQuant[.@i]+"x "+getitemname(.PremiosIDs[.@i]);
		logmes "[brA Ranking] "+(.@i+1)+"° "+.@fname$[.@i]+" ganhou "+.PremiosQuant[.@i]+"x "+getitemname(.PremiosIDs[.@i]);
	}
	next;
	mes "^358109brAthena PvP Ranking^000000";
	mes "Os prêmios já foram enviados.";
	mes "Mas o Ranking propriamente dito ainda não foi resetado.";
	mes "Gostaria de resetar agora ?";
	next;
	if (select ("Sim, continue.","Não, aborte a operação") == 2) goto L_end;
	
	L_sempremio:
	mes "^358109brAthena PvP Ranking^000000";
	mes "Só confirmando, você tem certeza disso ?";
	next;
	if (select ("Sim, continue.","Não, aborte a operação") == 2) goto L_end;
	query_sql("TRUNCATE `top_pvp`");
	logmes strcharinfo(0)+" resetou o Ranking PvP em: "+gettime(5)+"/"+gettime(6)+"/"+gettime(7)+" às "+gettime(3)+":"+gettime(2)+":"+gettime(1);
	mes "^358109brAthena PvP Ranking^000000";
	mes "O ranking foi resetado !";
	next;
	L_end:
	mes "^358109brAthena PvP Ranking^000000";
	mes "Okay... Até mais.";
	close;
	L_endusers:
	close;
	

OnPCKillEvent:
set .@killer_CID, getcharid(0);
set .@killer_AID, getcharid(3);

if ( !callfunc("isRankMap",strcharinfo(3)) ) end;
if (getgmlevel() > .LevelRankOn) end;

if (pvp_reset != $pvp_reset_global) {
	resetaHistoricoPvP();
}

if (query_sql("SELECT `points` FROM `top_pvp` WHERE `char_id`="+.@killer_CID+"",@ignore) == 0) {
	registraJogador(.@killer_CID);
	addKill(.@killer_CID,.add_pontos);
	dispbottom "Parabéns! Você fez seu primeiro ponto no Ranking!";
	end;
}

if ( killedrid == .@killer_AID ) { // Quem morreu = Quem matou, ganha morte apenas.
	addMorte(.@killer_CID,.rem_pontos);
	end;
}

// Aqui vai o script em quem morreu
attachrid(killedrid);

set .@killed_CID,getcharid(0);
set .@killed_AID,getcharid(3);
set .@killed_nome$, strcharinfo(0);
set .@killed_sex, Sex;

	if (query_sql("SELECT `points` FROM `top_pvp` WHERE `char_id`="+.@killed_CID+"",@ignore) == 1) {
		addMorte(.@killed_CID,.rem_pontos);
	}
detachrid;

// Aqui vai o script em quem matou
attachrid(.@killer_AID);

	if( .Anuncio){
		set @posicao, 0;
		set @nomechar$, strcharinfo(0);
		query_sql "SELECT name FROM top_pvp ORDER BY points DESC LIMIT "+.Tamanho+"",@fname$;
		for (set @i, 0; @i < .Tamanho && @posicao == 0; set @i, @i + 1){
			if(@fname$[@i] == @nomechar$){
				set @posicao,@i+1;
			}
		}
		if(@posicao == 0) set @posicao,.Tamanho+1; //"Finje" que o char esteja em (.Tamanho+1)°
	}//Sistema Anúncio
	
	if( .AntiSpam )
	{
		if( (callfunc("addAntiSpamList",.@killed_CID) -1 ) * .AS_Multiplica > rand(0,99) )
		{
			addKill(.@killer_CID,0); // Truque
			if( $@debugMode ) dispbottom "[Add-On: Anti-Spam] Os pontos serão ignorados através da Anti-Spam list. Mas os anúncios de kills por soms ou mensagems globais continuarão."; // debug msg
		}
		else{
			addKill(.@killer_CID,.add_pontos);
		}
	} 
	else{
		addKill(.@killer_CID,.add_pontos);
	} //Sistema Anti-Spam
	
	if( .Bonus){
		if( $@debugMode ) dispbottom "[Add-On: Bonus] Pontos por invictividade: "+@killsInvicto+"."; //debug msg
		set .@i, 0;
		while ( .indexInvicto[.@i] < @killsInvicto ) set .@i, .@i + 1;
		
		if( .indexInvicto[.@i] == @killsInvicto)
		{
			addBonus(.bonusInvicto[.@i],.@killer_CID);
			dispbottom .fraseInvicto$[.@i]+.bonusInvicto[.@i]+.fraseInvicto$[.@i]+.indexInvicto[.@i]+.fraseInvicto$[.@i];
		}
		
		set .@i, 0;
		while ( .indexMultiplo[.@i] < @killsTimed ) set .@i, .@i + 1;
		
		if( .indexMultiplo[.@i] == @killsTimed)
		{
			addBonus(.bonusMultiplo[.@i],.@killer_CID);
			dispbottom .fraseMultiplo$[.@i]+.bonusMultiplo[.@i]+.fraseMultiplo$[.@i]+.indexMultiplo[.@i]+.fraseMultiplo$[.@i];
		}
	}//Sistema Bônus
	
	if( .Soms){
		if( $@debugMode ) dispbottom "[Add-On: Soms] Pontos por invictividade: "+@killsInvicto+"."; //debug msg
		set .@i, 0;
		while ( .tipoDeSom[.@i] < @killsInvicto ) set .@i, .@i + 1;
		
		if( @killsInvicto == .tipoDeSom[.@i] ){
			set .@frase$, strcharinfo(0) +" "+ .fraseSom$[.@i]+" !";
			soundeffectall .nomesWAV$[.@i],0;
		}
		else if ( .maxSom > 0 && @killsInvicto != 0 && @killsInvicto % .tipoDeSom[.maxSom] == 0 ){
			set .@frase$, strcharinfo(0) +" "+ .fraseSom$[.maxSom]+" ["+(@killsInvicto/.tipoDeSom[.maxSom])+"] !";
			soundeffectall .nomesWAV$[.maxSom],0;
		}
		
		if( @killsInvicto == 0) set @killsInvicto, 1; // Por causa do First-Blood. Não retirar a não ser que saiba o que está fazendo.
		
		// Anúncios por tempo
		if( $@debugMode ) dispbottom "[Add-On: Soms] Pontos de Multiple Kills: "+@killsTimed+"."; //debug msg
		set .@i, 0;
		while ( .tipoDeSom2[.@i] < @killsTimed ) set .@i, .@i + 1;
		if( @killsTimed == .tipoDeSom2[.@i] ){
			set .@frase$, strcharinfo(0) +" "+ .fraseSom2$[.@i]+" !";
			soundeffectall .nomesWAV2$[.@i],0;
		}

		if (.@frase$ != "")
		{
			switch(.SomAnuncio){
				case 1:
						announce .@frase$,bc_area|bc_pc;
						break;
				case 2:
						announce .@frase$,bc_map|bc_pc;
						break;
			}
		}
	}//Sistema Soms
	
	if(.Anuncio){
	
		set @novaposicao, 0;
		query_sql "SELECT name FROM top_pvp ORDER BY points DESC LIMIT "+.Tamanho+"",@fname$;
		for (set @i, 0; @i < .Tamanho && @novaposicao == 0; set @i, @i + 1){
			if(@fname$[@i] == @nomechar$){
				set @novaposicao,@i+1;
			}
		}
		
		if(@novaposicao == 0){
			set @novaposicao,.Tamanho+1;
		}
		
		if($@debugMode && @posicao != @novaposicao){
			dispbottom "Mudanca de posicao! Posicao antiga: "+@posicao+" Nova posicao: "+@novaposicao+""; // debug msg
		}
		
		if ( @novaposicao < @posicao && (pvpmensagem == 2 || #pvpmensagem == 2 || (!#pvpmensagem && !pvpmensagem && .AnuncioPadrao) ) ){
			switch(.Anuncio){
				case 1:
						dispbottom "Você subiu de nível, agora você é o "+@novaposicao+"° do TOP "+.Tamanho+" PvP ! Depois de matar "+(.@killed_sex?"o":"a")+" "+.@killed_nome$+".";
						break;
				case 2:
						mapannounce strcharinfo(3),strcharinfo(0)+" subiu de nível, agora é o "+@novaposicao+"° do TOP "+.Tamanho+" PvP ! Depois de matar "+(.@killed_sex?"o":"a")+" "+.@killed_nome$+".",bc_map;
						break;
				case 3:
						announce strcharinfo(0)+" subiu de nível, agora é o "+@novaposicao+"° do TOP "+.Tamanho+" PvP ! Depois de matar "+(.@killed_sex?"o":"a")+" "+.@killed_nome$+".",bc_all,0x00FF00;
						break;
				default:
					break;
			}
		}
	} // Sistema anúncios
end;

	OnPCLoginEvent:	
	set .@CID, getcharid(0);
	set @killsInvicto, -1; // não mude.
	
	set .@max, getarraysize($premioRnkCid);
	for( set .@i,0; .@i < .@max; set .@i, .@i + 1)
	{
		if( .@CID == $premioRnkCid[.@i] && $premioRnkEnabled[.@i] == 1)
		{
			dispbottom "Parabéns "+strcharinfo(0)+", você acaba de ganhar prêmios por ficar em "+(.@i+1)+"° no ranking !";
			if (checkweight(.PremiosIDs[.@i],.PremiosQuant[.@i]) == 0 ){
				dispbottom "Desculpe, mas com seu peso atual não posso entregá-lo o item. Retire os excessos e relogue.";
				end;
			}
			getitem .PremiosIDs[.@i],.PremiosQuant[.@i];
			set $premioRnkEnabled[.@i], 0;
		}
	}
	end;
	
	function	resetaHistoricoPvP	{
		set @pvpPoints,0;
		set @pvpDeaths,0;
		set @pvpKills,0;
		set pvp_reset, $pvp_reset_global;
		return;
	}
	
	// Adiciona pontos relativos a uma morte.
	function	addMorte {
		set @killsInvicto, 0;
		set @pvpDeaths,@pvpDeaths + 1;
		set @pvpPoints,@pvpPoints - getarg(1);
		query_sql("UPDATE `top_pvp` SET `points` = `points` -"+getarg(1)+",`deaths` = `deaths` +1  WHERE `char_id`="+getarg(0)+"");
		return;
	}
	
	// Adiciona pontos relativos a um kill.
	function	addKill {
		if( getarg(1) > 0){
			set @pvpKills,@pvpKills + 1;
			set @pvpPoints,@pvpPoints + getarg(1);
			query_sql "UPDATE `top_pvp` SET `kills` = `kills` +1,`points` = `points` +"+getarg(1)+" WHERE `char_id`="+getarg(0)+"";
		}
		set @killsInvicto, @killsInvicto +1;
		set @tempoagora, gettimetick(1);
		if(@tempoagora - @tempoantes <= $@delay_combo) set @killsTimed, @killsTimed + 1;
		else{
			set @killsTimed, 1;
			if( $@debugMode ) dispbottom "Contagem de pontos \"múltiplos kills\" foi resetada."; //debug msg
		}
		set @tempoantes, @tempoagora;
		return;
	}
		
	// Adiciona pontos bônus.
	function	addBonus {
		set @pvpPoints,@pvpPoints + getarg(0);
		query_sql "UPDATE `top_pvp` SET `points` = `points` +"+getarg(0)+" WHERE `char_id`="+getarg(1)+"";
		return;
	}
	
	// Registra um jogador
	function	registraJogador {
		query_sql("SELECT `class` FROM `char` WHERE `char_id`="+getarg(0)+"",.@job);
		query_sql("INSERT INTO `top_pvp` (`char_id`,`name`,`points`,`kills`,`deaths`,`job`) VALUES ("+getarg(0)+",'"+strcharinfo(0)+"',0,0,0,"+.@job+")");
		return;
	}
}

// O que faz: Adiciona um mapa na lista de Ranked Maps.
// Entrada: Mapa (sem .gat)
// Saída: Retorna o índice em que o mapa está agora, -1 quando não pode ser adicionado com sucesso.
function	script	addRankMap	{
		set .@map$, getarg(0);
		for( set .@i, 0; .@i < ($@qtyMaps+1); set .@i, .@i + 1)
		{
			if( $@maps_pRank$[.@i] == .@map$)
			{
				if( $@debugMode ) debugmes "[brA Rank PvP] Mapa "+ .@map$+ " já está na lista !";
				return -1; // mapa repetido
			}
			
			if( $@maps_pRank$[.@i] == "")
			{
				setarray $@maps_pRank$[.@i], .@map$;
				if( $@debugMode ) debugmes "[brA Rank PvP] Mapa "+ .@map$+ " adicionado com sucesso na posição ["+ .@i +"] !";
				set $@qtyMaps, $@qtyMaps + 1;
				return .@i;
			}
		}
		if( $@secureMode ) debugmes "[brA Rank PvP] Mapa "+ .@map$+ " não pode ser adicionado ! Provavelmente existem scripts externos modificando as variaveis globais. Utilize somente addRankMap e rmRankMap !";
		return -1;
	}
	
// O que faz: Remove um mapa da lista de Ranked Maps.
// Entrada: Mapa (sem .gat)
// Saída: Retorna o índice em que o mapa estava, -1 quando o mapa não for encontrado.
function	script	rmRankMap	{
		set .@map$, getarg(0);
		for( set .@i, 0; .@i < $@qtyMaps; set .@i, .@i + 1)
		{
			if( $@maps_pRank$[.@i] == .@map$)
			{
				if( $@debugMode ) debugmes "[brA Rank PvP] Mapa "+ .@map$+ " removido com sucesso da posição ["+ .@i +"] !";
				deletearray $@maps_pRank$[.@i],1;
				set $@qtyMaps, $@qtyMaps - 1;
				return .@i;
			}
		}
		if( $@secureMode && .@map$ != "" ) debugmes "[brA Rank PvP] Mapa "+ .@map$+ " não pode ser removido ! Provavelmente existem scripts externos modificando as variaveis globais. Utilize somente addRankMap e rmRankMap !";
		return -1;
	}
	
// O que faz: Verifica se um mapa está na lista de ranked maps.
// Entrada: Mapa (sem .gat)
// Saída: 1 para sim, 0 para não.
function	script	isRankMap	{
		set .@map$, getarg(0);
		if( $@debugMode && playerattached()) dispbottom "N° mapas ranked pvp: "+$@qtyMaps;
		for( set .@i, 0; .@i < $@qtyMaps; set .@i, .@i + 1)
		{
			if( $@maps_pRank$[.@i] == .@map$)
			{
				if( $@debugMode && playerattached()) dispbottom .@map$+" é um mapa Ranked PvP"; // debug msg
				return 1;
			}
			if( $@debugMode && playerattached()) dispbottom "Comparando: "+$@maps_pRank$+" != "+.@map$; // debug msg
		}
		if( $@debugMode && playerattached()) dispbottom .@map$+" não é um mapa Ranked PvP"; // debug msg
		return 0;
	}

// Aqui temos uma lista cíclica.
// Bota no [0],[1],[2],[3],[4] e depois repete tudo denovo. (neste exemplo "$@AS_Limit" vale 5)
	
// Variáveis: @rnk_indice: Índice da lista cíclica.
// @rnk_cids[0],... : Array contendo char_ids de jogadores mortos.
// @rnk_counts[0],... : Array contendo count de jogadores mortos.
// @antiSpamTime : Marcador de segundos para a lista expirar.

// O que faz: Adiciona em um o valor ao CID especificado.
// Entrada: CID
// Saída: Quantas vezes este CID foi morto pelo jogador atachado.
function	script	addAntiSpamList	{
		set .@CID, getarg(0);
		
		if( (gettimetick(1) - @antiSpamTime) > ($@AS_Refresh*60) )
		{
			if( $@debugMode ){
				dispbottom "[Add-On: Anti-Spam] Spam-List resetada."; // debug msg
			}
			cleararray @rnk_cids[0],0,$@AS_Limit;
			set @antiSpamTime, gettimetick(1);
		}
		
		for( set @i, 0; @i < $@AS_Limit; set @i, @i + 1)
		{
			if( @rnk_cids[@i] == .@CID)
			{
				if( $@debugMode ){
					dispbottom "[Add-On: Anti-Spam] Vou aumentar em um o count para: "+.@CID+". Vai ficar: "+(@rnk_counts[@i]+1); // debug msg
				}
				return (set(@rnk_counts[@i],@rnk_counts[@i] + 1));
			}
		}
		set @rnk_cids[@rnk_indice], .@CID;
		set @rnk_counts[@rnk_indice], 1;
		if( $@debugMode ){
			dispbottom "[Add-On: Anti-Spam] Acabo de adicionar "+.@CID+" no slot ["+@rnk_indice+"]";
			}
		set @rnk_indice, @rnk_indice + 1;
		if( @rnk_indice == $@AS_Limit)
		{
			set @rnk_indice, 0;
		}
		else
		{
		set @rnk_indice, @rnk_indice + 1;
		}
		return 1;
	}
	
// Verifica se um CID está na lista anti-spam.
// Retorna número de vezes que o jogador que está atachado matou este CID ou retorna 0 (ou seja, não matou).
// OBS: Até agora não achei uma utilidade para esta função.

// O que faz: Verifica se um determinado CID está na lista anti-spam de um jogador.
// Entrada: CID
// Saída: Quantas vezes este CID foi morto pelo jogador atachado, retorna 0 se não consta na lista.
function	script	isOnList	{
		set .@CID, getarg(0);
		
		if( (gettimetick(1) - @antiSpamTime) > ($@AS_Refresh*60) )
		{
			cleararray @rnk_cids[0],0,$@AS_Limit;
			set @antiSpamTime, gettimetick(1);
			if( $@debugMode ){ 
				dispbottom "[Add-On: Anti-Spam] Spam-List resetada."; // debug msg
			}
		}
		
		for( set @i, 0; @i < $@AS_Limit; set @i, @i + 1)
		{
			if( @rnk_cids[@i] == .@CID)
			{
				if( $@debugMode ){
					dispbottom "[Add-On: Anti-Spam] O char "+.@CID+" está na lista"; // debug msg
				}
				return (@rnk_counts[@i]);
			}
		}
		if( $@debugMode ){
			dispbottom "[Add-On: Anti-Spam] O char "+.@CID+" não está na lista"; // debug msg
		}
		return 0;
	}
	
// Qual a diferença entre addAntiSpamList para isOnList ? A única diferença é que o addAntiSpamList aumenta em um o valor neste CID e caso ele não exista, cria ele.